AutoHotkey Script to auto-fill the Gold Farmer reporting tool.

DewiMorgan

If you position your cursor over someone's name in chat and hit F12, the following AHK script will fill out the reporting tool with the phrase "Gold spammer", will select to add a screenshot, and will select "I wish to report spam" from the dropdown.

You will need to take a screenshot of your reporting screen at your preferred resolution, and find out and type in the coordinates for that, replacing the coordinates I have used. My resolution is windowed 1920x1138. Yours will almost certainly not be.

There are three significant things that it does NOT do.
- It does not auto-detect spammers. There are add-ons for this. I considered tying into them, and it would be possible with a little semaphore window, but I really don't want to. There's just too high a risk of spamming tech support with false-positives from badly configured regexes. Plus, if it fired at the same time as auto-ignoring... that could be a BAD time for the reporting tool to come up!
- It does not auto-submit the form. It could. But it's way better that you get to check it over before it submits, to make sure it selected the right person, and so on. But instead of lots of clicks and faffing, it's one key-hit, and one mouseclick.
- It does not auto-adapt to your screen resolution. If there's any interest, I'll make it do that, but I suspect this will be something nobody but me will ever use, so, not worth it.

; Script Function:
; Form filler for reporting gold spammers.
#SingleInstance force
SendMode Input
return

#IfWinActive ahk_class EsoClientWndClass

F12::
{
	; Bring up the rightclick menu on the name.
	Click right

	; Select the option to report.
	MouseMove 40, 128, 0, R
	Sleep 200
	Click

	; Wait for the feedback form to appear.
	endTime := A_TickCount + 6000
	Loop {
		PixelGetColor, color, 1300, 750, RGB
		if (color == 0x424135) {
			break
		}
		; But don't loop forever.
		if (endTime < A_TickCount) {
			return
		}
	}

	; Input description of offense.
	MouseMove 1300, 750
	Sleep 200
	Click
	Sleep 200
	SendInput Gold Spammer

	; Include screenshot of offense, so they have evidence.
	MouseMove 1220, 810
	Sleep 200
	Click

	; Bring down menu of offense types.
	MouseMove 1300, 515
	Sleep 200
	Click

	; Select offense: spamming.
	MouseMove 1300, 615
	Sleep 200
	Click

	; Move mouse over submit button.
	MouseMove 1180, 870
	Sleep 200
	;Click - but we don't click it! Leave that to the user.
}
#IfWinActive